SAS Certification

What Is a Published Document?

2009-08-19T07:23:00.000-07:00

After you have completed an analysis, you might want to share the results with others at your site. Published documents are Excel, Word, or PowerPoint documents that are saved to a common repository.
Publishing your documents to a common repository has the following benefits:
§ The workbooks, documents, and presentations in this repository can be opened by others at your site.
§ When you publish the workbook, document, or presentation to the metadata repository, information about all the data sources is saved to the repository. Storing this metadata in the repository enables you to perform an impact analysis on a document. Impact analysis enables you to see where a data source came from and the items that depend on this source. This analysis enables you to know how changing a data source might affect other documents.

Note
To publish a document, your site administrator must have installed SAS Web Report Studio on the same metadata server. If you cannot publish documents, contact your site administrator. D

Sending Results from Excel

2009-08-18T07:22:00.000-07:00

After you performed your initial analysis of the company’s 2006 sales data in Excel, your managers asked you to create a short presentation for the yearly sales meeting. This presentation should include the following:
§ the total sales for each product
§ the average sales, inventory, and returns for each product
From Excel, you can select the results from the Shoe Sales 2006 workbook to send to Word or to PowerPoint. When you select the SAS content to send, the current results for that analysis are automatically displayed in Word or PowerPoint. To make sure that the most up-to-date results are displayed in Word or PowerPoint, you should refresh the analysis after the results are sent to these applications.

Note
You can send only SAS content from Excel to Word or PowerPoint. Any formatting or text changes that you made to the SAS content are not sent. Only the results are re-opened in Word or PowerPoint.
You cannot send a SAS data source or data in an Excel worksheet. Word and PowerPoint are unable to open and read an Excel data source. Additionally, you cannot send a PivotTable report to Word or PowerPoint. D

Accessibility Features of the SAS Add-In for Microsoft Office

2009-08-17T07:21:00.000-07:00

The SAS Add-In for Microsoft Office includes accessibility and compatibility features that improve usability of the product for users with disabilities. These features are related to accessibility standards for electronic information technology adopted by the U.S. Government under Section 508 of the U.S. Rehabilitation Act of 1973, as amended. For more information about the accessibility of the SAS Add-In for Microsoft, see the online Help.

Benefits to Using the SAS Add-In for Microsoft Office

2009-08-16T07:20:00.000-07:00

Most of the SAS add-in functionality is identical in Excel, Word, and PowerPoint; for example, you can run analyses and reports in all three applications.
The SAS add-in extends the functionality in Excel, Word, and PowerPoint by enabling you to complete the following tasks:
§ Access SAS data sources as the input data for your analysis. You can view any SAS data source or any data source available from your SAS server (including databases such as Oracle, Teradata, and DB2).
§ Perform more sophisticated analysis and computations than what is available in Microsoft Excel. For example, one of the sophisticated analyses that SAS provides is the Canonical Correlation task. This task enables you to examine the relationship between a linear combination of a set of X variables and a linear combination of a set of Y variables. You might run a canonical correlation analysis to determine the degree of correspondence between a set of job characteristics and a set of measures of employee satisfaction. This extends the correlation analysis that is available in Excel. You can run these sophisticated analyses and computations in Excel, Word, or PowerPoint.
§ Run custom analyses that were developed by others at your company. Using the SAS add-in, you can also access programs, which are called SAS Stored Processes. These programs are customized SAS code that is developed by business analysts or your IT department. Running these programs enables you to quickly generate a custom report without writing any SAS code.
§ Refresh the content in the Excel worksheet, Word document, or PowerPoint presentation on demand or automatically at a specified time. Scheduling when the content is refreshed enables you to have the most up-to-date data and reports when you need it.
§ Publish the results to a central location. By publishing a document, you can share it with others without having to e-mail it. If you publish the document to a metadata repository, then you can perform an impact analysis on the document. Impact analysis enables you to see where a data source came from and the items that are dependent on this source. This analysis enables you to know how changing a data source might affect other documents.
Additional functionality is available in Excel. In Microsoft Excel, you can also complete the following tasks:
§ Access and view data sources that exceed the 65,536 record limitation in Excel. The SAS add-in does its processing on the server, which enables it to by-pass the record limitation in Excel.
§ Copy data to a SAS server. You can copy an Excel data source or a SAS data source to the SAS server. After a data source is copied to a SAS server, it becomes a SAS data set. This enables you to share Excel data with Word and PowerPoint users at your site. This functionality also enables Excel users to update information in a SAS data source and upload it to the SAS server.
§ Send the results from an analysis that you ran in Excel to a Word document or PowerPoint presentation. For example, you ran analysis of your company’s sales for this year, and now you need to give a presentation of the results. Using this functionality in Excel, you can select which results to include in a PowerPoint presentation. This saves you time because you only need to run the analysis once.
This book explores some of the basic tasks that you can perform in Excel.

What Is the SAS Add-In for Microsoft Office?

2009-08-15T07:18:00.000-07:00

The SAS Add-In for Microsoft Office extends the functionality of Microsoft Excel, Microsoft Word, and Microsoft PowerPoint by enabling you to access SAS analytics and SAS reporting functionality without any SAS programming experience. The SAS add-in is designed for users who are familiar with these Microsoft Office programs but who might be new to SAS.
The SAS add-in includes approximately 80 SAS tasks that enable you to perform a variety of analyses. Examples of analyses that you can perform include linear and nonlinear regressions, multivariate analyses, time series analyses, one-way frequencies, and summary statistics. The SAS add-in enables you to refresh these analyses so that your results include the most up-to-date information. You can also easily share the results with others at your site.
When the SAS add-in is installed on your computer, a SAS menu and the SAS Analysis Tools toolbar are automatically integrated into Excel, Word, and PowerPoint. (In Excel, the SAS Data Tools toolbar is also available.) The menu and toolbars enable you to access the SAS analytics and reporting functionality directly from these Microsoft Office programs without having to open a separate SAS interface.

Functions That Change the Case of Characters 5

2008-09-15T00:20:00.000-07:00

UPCASE 6

LOWCASE 7

PROPCASE 9

Functions That Remove Characters from Strings 11

COMPBL 11

COMPRESS 13

Functions That Search for Characters 16

ANYALNUM 17 NOTUPPER 27

ANYALPHA 18 FIND 29

ANYDIGIT 19 FINDC 31

ANYPUNCT 20 INDEX 34

ANYSPACE 21 INDEXC 36

NOTALNUM 24 INDEXW 39

NOTALPHA 25 VERIFY 41

NOTDIGIT 26

Functions That Extract Parts of Strings 43

SUBSTR 43

SUBSTRN 49

Functions That Join Two or More Strings Together 51

CALL CATS 52 CATS 57

CALL CATT 53 CATT 58

CALL CATX 53 CATX 59

CAT 56

2 SAS Functions by Example

Functions That Remove Blanks from Strings 61

LEFT 61 TRIMN 66

RIGHT 63 STRIP 68

TRIM 64

Functions That Compare Strings (Exact and "Fuzzy" Comparisons) 70

COMPARE 70 COMPLEV 76

CALL COMPCOST 73 SOUNDEX 81

COMPGED 74 SPEDIS 84

Functions That Divide Strings into "Words" 89

SCAN 89

SCANQ 90

CALL SCAN 95

CALL SCANQ 98

Functions That Substitute Letters or Words in Strings 100

TRANSLATE 100

TRANWRD 103

Functions That Compute the Length of Strings 105

LENGTH 105

LENGTHC 106

LENGTHM 106

LENGTHN 107

Functions That Count the Number of Letters or Substrings in a String 109

COUNT 109

COUNTC 111

Miscellaneous String Functions 113

MISSING 113

RANK 115

REPEAT 117

REVERSE 119

Chapter 1: Character Functions 3

Introduction

A major strength of SAS is its ability to work with character data. The SAS character

functions are essential to this. The collection of functions and call routines in this chapter

allow you to do extensive manipulation on all sorts of character data.

SAS users who are new to Version 9 will notice the tremendous increase in the number of

SAS character functions. You will also want to review the next chapter on Perl regular

expressions, another way to process character data.

Before delving into the realm of character functions, it is important to understand how SAS

stores character data and how the length of character variables gets assigned.

Storage Length for Character Variables

It is in the compile stage of the DATA step that SAS variables are determined to be character

or numeric, that the storage lengths of SAS character variables are determined, and that the

descriptor portion of the SAS data set is written. The program below will help you to

understand how character storage lengths are determined:

Program 1.1: How SAS determines storage lengths of character variables

DATA EXAMPLE1;

INPUT GROUP $

@10 STRING $3.;

LEFT = 'X '; *X AND 4 BLANKS;

RIGHT = ' X'; *4 BLANKS AND X;

SUB = SUBSTR(GROUP,1,2);

REP = REPEAT(GROUP,1);

DATALINES;

ABCDEFGH 123

XXX 4

Y 5

;

Explanation

The purpose of this program is not to demonstrate SAS character functions. That is why the

functions in this program are not highlighted as they are in all the other programs in this

book. Let's look at each of the character variables created in this DATA step. To see the

storage length for each of the variables in data set EXAMPLE1, let's run PROC

CONTENTS. Here is the program:

4 SAS Functions by Example

Program 1.2: Running PROC CONTENTS to determine storage lengths

PROC CONTENTS DATA=EXAMPLE1 VARNUM;

TITLE "PROC CONTENTS for Data Set EXAMPLE1";

RUN;

The VARNUM option requests the variables to be in the order that they appear in the SAS

data set, rather than the default, alphabetical order. The output is shown next:

-----Variables Ordered by Position-----

# Variable Type Len

ƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒ

1 GROUP Char 8

2 STRING Char 3

3 LEFT Char 5

4 RIGHT Char 5

5 SUB Char 8

6 REP Char 200

First, GROUP is read using list input. No informat is used, so SAS will give the variable the

default length of 8. Since STRING is read with an informat, the length is set to the informat

width of 3. LEFT and RIGHT are both created with an assignment statement. Therefore the

length of these two variables is equal to the number of bytes in the literals following the

equal sign. Note that if a variable appears several times in a DATA step, its length is

determined by the first reference to that variable.

For example, beginning SAS programmers often get in trouble with statements such as:

IF SEX = 1 THEN GENDER = 'MALE';

ELSE IF SEX = 2 THEN GENDER = 'FEMALE';

The length of GENDER in the two lines above is 4, since the statement in which the variable

first appears defines its length.

There are several ways to make sure a character variable is assigned the proper length.

Probably the best way is to use a LENGTH statement. So, if you precede the two lines

above with the statement:

LENGTH GENDER $ 6;

Chapter 1: Character Functions 5

the length of GENDER will be 6, not 4. Some lazy programmers will "cheat" by adding two

blanks after MALE in the assignment statement (me, never!). Another trick is to place the

line for FEMALE first.

So, continuing on to the last two variables. You see a length of 8 for the variable SUB. As

you will see later in this chapter, the SUBSTR (substring) function can extract some or all of

one string and assign the result to a new variable. Since SAS has to determine variable

lengths in the compile stage and since the SUBSTR arguments that define the starting point

and the length of the substring could possibly be determined in the execution stage (from

data values, for example), SAS does the logical thing: it gives the variable defined by the

SUBSTR function the longest length it possibly could—the length of the string from which

you are taking the substring.

Finally, the variable REP is created by using the REPEAT function. As you will find out

later in this chapter, the REPEAT function takes a string and repeats it as many times as

directed by the second argument to the function. Using the same logic as the SUBSTR

function, since the length of REP is determined in the compile stage and since the number of

repetitions could vary, SAS gives it a default length of 200. A note of historical interest:

Prior to Version 7, the maximum length of character variables was 200. With the coming of

Version 7, the maximum length of character variables was increased to 32,767. SAS made a

very wise decision to leave the default length for situations such as the REPEAT function

described here, at 200. The take-home message is that you should always be sure that you

know the storage lengths of your character variables.

Functions That Change the Case of Characters

Two old functions, UPCASE and LOWCASE, change the case of characters. A new

function (as of Version 9), PROPCASE (proper case) capitalizes the first letter of each word.

6 SAS Functions by Example

Function: UPCASE

Purpose: To change all letters to uppercase.

Note: The corresponding function LOWCASE changes uppercase to

lowercase.

Syntax: UPCASE(character-value)

character-value is any SAS character expression.

If a length has not been previously assigned, the length of the resulting

variable will be the length of the argument.

Examples

For these examples CHAR = "ABCxyz"

Function Returns

UPCASE(CHAR) "ABCXYZ"

UPCASE("a1%m?") "A1%M?"

Program 1.3: Changing lowercase to uppercase for all character variables

in a data set

***Primary function: UPCASE

***Other function: DIM;

DATA MIXED;

LENGTH A B C D E $ 1;

INPUT A B C D E X Y;

DATALINES;

M f P p D 1 2

m f m F M 3 4

;

DATA UPPER;

SET MIXED;

ARRAY ALL_C[*] _CHARACTER_;

DO I = 1 TO DIM(ALL_C);

ALL_C[I] = UPCASE(ALL_C[I]);

END;

Chapter 1: Character Functions 7

DROP I;

RUN;

PROC PRINT DATA=UPPER NOOBS;

TITLE 'Listing of Data Set UPPER';

RUN;

Explanation

Remember that upper- and lowercase values are represented by different internal codes, so if

you are testing for a value such as Y for a variable and the actual value is y, you will not get

a match. Therefore it is often useful to convert all character values to either upper- or

lowercase before doing your logical comparisons. In this program, _CHARACTER_ is used

in the array statement to represent all the character variables in the data set MIXED.

Inspection of the listing below verifies that all lowercase values were changed to uppercase.

Listing of Data Set UPPER

A B C D E X Y

M F P P D 1 2

M F M F M 3 4

Function: LOWCASE

Purpose: To change all letters to lowercase.

Syntax: LOWCASE(character-value)

character-value is any SAS character expression.

Note: The corresponding function UPCASE changes lowercase to

uppercase.

If a length has not been previously assigned, the length of the resulting

variable will be the length of the argument.

8 SAS Functions by Example

Examples

For these examples CHAR = "ABCxyz"

Function Returns

LOWCASE(CHAR) "abcxyz"

LOWCASE("A1%M?") "a1%m?"

Program 1.4: Program to capitalize the first letter of the first and last

name (using SUBSTR)

***Primary functions: LOWCASE, UPCASE

***Other function: SUBSTR (used on the left and right side of the equal

sign);

DATA CAPITALIZE;

INFORMAT FIRST LAST $30.;

INPUT FIRST LAST;

FIRST = LOWCASE(FIRST);

LAST = LOWCASE(LAST);

SUBSTR(FIRST,1,1) = UPCASE(SUBSTR(FIRST,1,1));

SUBSTR(LAST,1,1) = UPCASE(SUBSTR(LAST,1,1));

DATALINES;

ronald cODy

THomaS eDISON

albert einstein

;

PROC PRINT DATA=CAPITALIZE NOOBS;

TITLE "Listing of Data Set CAPITALIZE";

RUN;

Explanation

Before we get started on the explanation, I should point out that as of Version 9, the

PROPCASE function capitalizes the first letter of each word in a string. However, it

provides a good demonstation of the LOWCASE and UPCASE functions and this method

will still be useful for SAS users using earlier versions of SAS software.

This program capitalizes the first letter of the two character variables FIRST and LAST.

The same technique could have other applications. The first step is to set all the letters to

lowercase using the LOWCASE function. The first letter of each name is then turned back

to uppercase using the SUBSTR function (on the right side of the equal sign) to select the

first letter in the first and last names, and the UPCASE function to capitalize it. The

Chapter 1: Character Functions 9

SUBSTR function on the left side of the equal sign is used to place this letter in the first

position of each of the variables. The listing below shows that this program worked as

desired:

Listing of Data Set CAPITALIZE

FIRST LAST

Ronald Cody

Thomas Edison

Albert Einstein

Function: PROPCASE

Purpose: To capitalize the first letter of each word in a string.

Syntax: PROPCASE(character-value)

character-value is any SAS character expression.

If a length has not been previously assigned, the length of the resulting

variable will be the length of the argument.

Examples

For these examples CHAR = "ABCxyz"

Function Returns

PROPCASE(CHAR) "Abcxyz"

PROPCASE("a1%m?") "A1%m?"

PROPCASE("mr. george w. bush") "Mr. George W. Bush"

Program 1.5: Capitalizing the first letter of each word in a string

***Primary function: PROPCASE;

DATA PROPER;

INPUT NAME $60.;

NAME = PROPCASE(NAME);

10 SAS Functions by Example

DATALINES;

ronald cODy

THomaS eDISON

albert einstein

;

PROC PRINT DATA=PROPER NOOBS;

TITLE "Listing of Data Set PROPER";

RUN;

Explanation

In this program, you use the PROPCASE function to capitalize the first letter of the first and

last names. The listing is shown below:

Listing of Data Set PROPER

NAME

Ronald Cody

Thomas Edison

Albert Einstein

Program 1.6: Alternative program to capitalize the first letter of each

word in a string

***First and last name are two separate variables.

DATA PROPER;

INFORMAT FIRST LAST $30.;

INPUT FIRST LAST;

LENGTH NAME $ 60;

CALL CATX(' ', NAME, FIRST, LAST);

NAME = PROPCASE(NAME);

DATALINES;

ronald cODy

THomaS eDISON

albert einstein

;

PROC PRINT DATA=PROPER NOOBS;

TITLE "Listing of Data Set PROPER";

RUN;

Chapter 1: Character Functions 11

Explanation

In this alternative program, the CATX call routine is used to concatenate the first and last

name with a blank as the separator character. The PROPCASE function is then used the

same way as above. The listing is identical to the listing above.

Functions That Remove Characters from Strings

COMPBL (compress blanks) can replace multiple blanks with a single blank. The

COMPRESS function can remove not only blanks, but also any characters you specify from

a string.

Function: COMPBL

Purpose: To replace all occurrences of two or more blanks with a single blank

character. This is particularly useful for standardizing addresses and names

where multiple blanks may have been entered.

Syntax: COMPBL(character-value)

character-value is any SAS character expression.

If a length has not been previously assigned, the length of the resulting

variable will be the length of the argument.

Example

For these examples CHAR = "A C XYZ"

Function Returns

COMPBL(CHAR) "A C XYZ"

COMPBL("X Y Z LAST") "X Y Z LAST"

12 SAS Functions by Example

Program 1.7: Using the COMPBL function to convert multiple blanks to a

single blank

***Primary function: COMPBL;

DATA SQUEEZE;

INPUT #1 @1 NAME $20.

#2 @1 ADDRESS $30.

#3 @1 CITY $15.

@20 STATE $2.

@25 ZIP $5.;

NAME = COMPBL(NAME);

ADDRESS = COMPBL(ADDRESS);

CITY = COMPBL(CITY);

DATALINES;

RON CODY

89 LAZY BROOK ROAD

FLEMINGTON NJ 08822

BILL BROWN

28 CATHY STREET

NORTH CITY NY 11518

;

PROC PRINT DATA=SQUEEZE;

TITLE 'Listing of Data Set SQUEEZE';

ID NAME;

VAR ADDRESS CITY STATE ZIP;

RUN;

Explanation

Each line of the addresses was passed through the COMPBL function to replace any

sequence of two or more blanks to a single blank. A listing of data set SQUEEZE is shown

below:

Listing of Data Set SQUEEZE

NAME ADDRESS CITY STATE ZIP

RON CODY 89 LAZY BROOK ROAD FLEMINGTON NJ 08822

BILL BROWN 28 CATHY STREET NORTH CITY NY 11518

Chapter 1: Character Functions 13

Function: COMPRESS

Purpose: To remove specified characters from a character value.

Syntax: COMPRESS(character-value <,'compress-list'>)

character-value is any SAS character expression.

compress-list is an optional list of the characters you want to remove.

If this argument is omitted, the default character to be removed is a blank. If

you include a list of values to remove, only those characters will be

removed. If a blank is not included in the list, blanks will not be removed.

If a length has not been previously assigned, the length of the resulting

variable will be the length of the argument.

Examples

In the examples below, CHAR = "A C123XYZ"

Function Returns

COMPRESS("A C XYZ") "ACXYZ"

COMPRESS("(908) 777-1234"," (-)") "9087771234"

COMPRESS(CHAR,"0123456789") "A CXYZ"

Program 1.8: Removing dashes and parentheses from phone numbers

***Primary function: COMPRESS;

DATA PHONE_NUMBER;

INPUT PHONE $ 1-15;

PHONE1 = COMPRESS(PHONE);

PHONE2 = COMPRESS(PHONE,'(-) ');

DATALINES;

(908)235-4490

(201) 555-77 99

;

PROC PRINT DATA=PHONE_NUMBER;

TITLE 'Listing of Data Set PHONE_NUMBER';

RUN;

14 SAS Functions by Example

Explanation

For the variable PHONE1, the second argument is omitted from the COMPRESS function;

therefore, only blanks are removed. For PHONE2, left and right parentheses, dashes, and

blanks are listed in the second argument so all of these characters are removed from the

character value. You can verify this by inspecting the listing below:

Listing of Data Set PHONE_NUMBER

Obs PHONE PHONE1 PHONE2

1 (908)235-4490 (908)235-4490 9082354490

2 (201) 555-77 99 (201)555-7799 2015557799

Converting Social Security Numbers to Numeric Form

Here is another example where the COMPRESS function makes it easy to convert a standard

social security number, including the dashes, to a numeric value.

Program 1.9: Converting social security numbers from character to

numeric

***Primary function: COMPRESS

***Other function: INPUT;

DATA SOCIAL;

INPUT @1 SS_CHAR $11.

@1 MIKE_ZDEB COMMA11.;

SS_NUMERIC = INPUT(COMPRESS(SS_CHAR,'-'),9.);

SS_FORMATTED = SS_NUMERIC;

FORMAT SS_FORMATTED SSN.;

DATALINES;

123-45-6789

001-11-1111

;

PROC PRINT DATA=SOCIAL NOOBS;

TITLE "Listing of Data Set SOCIAL";

RUN;

Chapter 1: Character Functions 15

Explanation

The COMPRESS function is used to remove the dashes from the social security number and

the INPUT function does the character to numeric conversion.

It should be noted here that the social security number, including dashes, can be read directly

into a numeric variable using the comma11. informat. This trick was brought to light by

Mike Zdeb in a NESUG workshop in Buffalo in the Fall of 2002. Here, the variable

SS_FORMATTED is set equal to the variable SS_NUMERIC so that you can see the effect

of adding the SSN. format. (Note: SSN. is equivalent to SSN11.) This format prints numeric

values with leading zeros and dashes in the proper places, as you can see in the listing

below:

Listing of Data Set SOCIAL

SS_CHAR MIKE_ZDEB SS_NUMERIC SS_FORMATTED

123-45-6789 123456789 123456789 123-45-6789

001-11-1111 1111111 1111111 001-11-1111

Counting the Number of Digits in a Character String

This program computes the number of numerals (i.e., digits) in a string by a novel method.

It uses the COMPRESS function to remove all digits from the string and then subtracts the

resulting length from the original length for the computation.

Program 1.10: Counting the number of numerals in a string

***Primary functions: COMPRESS, LENGTHN;

DATA COUNT;

INPUT STRING $20.;

ONLY_LETTERS = COMPRESS(STRING,'0123456789');

NUM_NUMERALS = LENGTHN(STRING) - LENGTHN(ONLY_LETTERS);

DATALINES;

ABC123XYZ

XXXXX

12345

1234X

;

16 SAS Functions by Example

PROC PRINT DATA=COUNT NOOBS;

TITLE "Listing of Data Set COUNT";

RUN;

Explanation

This is an interesting application of the COMPRESS function. By computing the length of

the string before and after removing the numerals, this program sets the difference in the

lengths to the number of numerals in the original string. Notice the use of the LENGTHN

function instead of the LENGTH function. When the COMPRESS function operates on the

third observation (all digits), the result is a null string. The LENGTH function returns a

value of 1 in this situation; the LENGTHN function returns a value of 0. See LENGTH and

LENGTHN function descriptions for a detailed explanation.

Listing of Data Set COUNT

ONLY_ NUM_

STRING LETTERS NUMERALS

ABC123XYZ ABCXYZ 3

XXXXX XXXXX 0

12345 5

1234X X 4

Functions That Search for Characters

Functions in this category allow you to search a string for specific characters or for a

character category (such as a digit). Some of these functions can also locate the first position

in a string where a character does not meet a particular specification. Quite a few of the

functions in this section are new to Version 9 and they provide some new and useful

capabilities.

The "ANY" functions (ANYALNUM, ANYALPHA, ANYDIGIT,

ANYPUNCT, and ANYSPACE)

This group of functions is described together because of the similarity of their use. New as

of Version 9, these functions return the location of the first alphanumeric, letter, digit,

punctuation, or space in a character string. Note that there are other "ANY" functions

Chapter 1: Character Functions 17

besides those presented here—these are the most common ones (see the SAS OnlineDoc 9.1

for a complete list). The functionality of this group of functions is similar to many of the

Perl regular expressions that are also available in Version 9.

It is important to note that it may be necessary to use the TRIM function (or STRIP function)

with the ANY and NOT functions since leading or, especially, trailing blanks will affect the

results. For example, if X = "ABC " (ABC followed by three blanks), Y =

NOTALNUM(X) will be 4, the location of the first blank. Therefore, you may want to

routinely use TRIM (or STRIP) like this:

Y = NOT or ANY function(TRIM(X));

Note that there are a group of similar functions NOTALPHA, NOTDIGIT, etc. that work in

a similar manner and are described together later in the next section. One program example

follows the description of these five functions.

Function: ANYALNUM

Purpose: To locate the first occurrence of an alphanumeric character (any upper- or

lowercase letter or number) and return its position. If none is found, the

function returns a 0. With the use of an optional parameter, this function

can begin searching at any position in the string and can also search from

right to left, if desired.

Syntax: ANYALNUM(character-value <,start>)

character-value is any SAS character expression.

start is an optional parameter that specifies the position in the string to

begin the search. If it is omitted, the search starts at the beginning of the

string. If it is non-zero, the search begins at the position in the string of the

absolute value of the number (starting from the left-most position in the

string). If the start value is positive, the search goes from left to right; if the

value is negative, the search goes from right to left. A negative value larger

than the length of the string results in a scan from right to left, starting at the

end of the string. If the value of start is a positive number longer than the

length of the string, or if it is 0, the function returns a 0.

18 SAS Functions by Example

Examples

For these examples, STRING = "ABC 123 ?xyz_n_"

Function Returns

ANYALNUM(STRING) 1 (the position of "A")

ANYALNUM("??$$%%") 0 (no alpha-numeric characters)

ANYALNUM(STRING,5) 5 (the position of "1")

ANYALNUM(STRING,-4) 3 (the position of "C")

ANYALNUM(STRING,6) 6 (the position of "2")

Function: ANYALPHA

Purpose: To locate the first occurrence of an alpha character (any upper- or lowercase

letter) and return its position. If none is found, the function returns a 0. With

the use of an optional parameter, this function can begin searching at any

position in the string and can also search from right to left, if desired.

Syntax: ANYALPHA(character-value <,start>)